IIS / Tools / Scripts

Starting and Stopping a Web Site And Application Pool

Chris Crowe — Tue, 21 Aug 2007 00:50:24 GMT

I had a request last week for the following:

I'm trying to do the following:

Stop a IIS website
Stop an App Pool
Start the App Pool
Start the Website

From what I can see here, I can use the example for the "starting an application pool" for the steps 2 & 3.

I have found that you can use iisweb.vbs to do steps 1 & 4.

But how link them in the order above?

Hope you can give me some pointers

The following code sample in VBScript allows you to do that with the following points of interest.

The Default Web Site is assumed - WebSiteID = 1, you can change this to any other web site by changing the ID with the ID of the other web site. There is a script called FindWeb.VBS or you can look at the log folder name and get the web site id from that - see http://blog.crowe.co.nz/archive/2007/08/04/IIS-Web-Site-Identifiers.aspx
There is only 1 site using the AppPool - well not technically true, if you run this and there is more than one web site using the app pool then it will be down while the app pool restarts.

Here is the code, save to StopAndStartSiteAndAppPool.VBS file and then run in a CMD.EXE prompt using the following syntax:

cscript StopAndStartSiteAndAppPool.VBS

Option Explicit

Dim WebSiteID, objWebSite, ObjAppPool

WebSiteID = "1"
Set objWebSite = GetObject("IIS://localhost/W3SVC/" & WebSiteID)
WScript.Echo "Stopping Web Site : " & objWebSite.ServerComment \
objWebSite.Stop()

wscript.echo "Stopping Application Pool : " & objWebSite.AppPoolID
Set objAppPool = GetObject("IIS://localhost/W3SVC/AppPools/" & objWebSite.AppPoolID)
objAppPool.Stop()

wscript.echo "Starting Application Pool : " & objWebSite.AppPoolID
objAppPool.Start()

WScript.Echo "Starting Web Site : " & objWebSite.ServerComment
objWebSite.Start()

You can also view/save the script from here.

IIS Web Site Identifiers

Chris Crowe — Sat, 04 Aug 2007 17:15:12 GMT

Normally you do not need to be concerned about web site identifiers, these are the actual ID's that reference the web site to IIS. Normally we just use the web site description such as Default Web Site or in my case blog.crowe.co.nz or something similar.

But if you are interested in writing scripts you normally reference sites using the Web Site Instance ID.

In IIS 6 the IIS Manager shows you a column called Idenfitier and this is the actual ID that references the web site. This was not visible in Windows 2000 (IIS 5) or Windows XP (IIS 5.1) and we had to use different methods to see the identifier.

Using IIS 7 on Windows Vista you can see a column called ID which is the Web Site Instance ID

The Default Web Site always has an identifier of 1.

All other web sites on IIS 6 have web site idenfieir's that look like random numbers. The fact is that this is not the case and the identifier is generated based on the description of the web site. This is so that if you have a server farm as long as the descripiton is the same you will end up with the same web site identifier. See this article for more details on the way that these identifiers are generated.

Another way to identify the web site instance id is to look at the Logging Properties of a particular web site.

As you can see above the highlighted area shows the web site instance id. This is still a valid method for people using IIS 5 and IIS 5.1.

IIS 7 on Windows Vista does not include a logging configuration option - did they just forget it?

How about if you want to use a script to identify a web site?

IIS comes with a script called findweb.vbs that you can use to find a particular web site. This script is stored in c:\inetpub\adminscripts by default.

To use it you need to open a CMD.EXE command prompt and then use the cscript.exe utility to run the script. You also need to specify parameters to get the script to do what you want.

In this case I was interested in finding a web site called photos.crowe.co.nz

How about writing your own VB Script to list the site and the instance id?

Running the script above will display the web site Instance ID and the Description of the site.

Microsoft releases a new download center for IIS (everything in one place)

Chris Crowe — Thu, 01 Feb 2007 19:36:00 GMT

DownloadCENTER for IIS.net has been released!

The DownloadCENTER at IIS.net, is a community hotspot for discovering, sharing, reviewing and promoting IIS-related solutions in a single place. Dozens of existing downloads, for all versions of IIS – both from Microsoft and the community – are already available in DownloadCENTER today.

This new feature of IIS.net is particularly relevant with the release of IIS7 in Windows Vista. The latest release of Microsoft’s Web server has a completely modular architecture which features over forty pluggable components that can be easily added, removed or even replaced with custom implementations.

This powerful extensibility support is available to both .NET and C/C++ developers. In the future, DownloadCENTER is expected to house a large number of IIS7 extensions submitted by not only the IIS team but the developers and partner ISVs of the IIS community as well.

To learn more about the DownloadCenter, read IIS Product Unit Manager, Bill Staples’ blog post about it or check it out yourself today!

VBScript - Check if multiple version of the .NET framework are assigned to an application pool

Chris Crowe — Tue, 15 Aug 2006 20:31:00 GMT

This code will allow you to check if there are IIS applications which are configured to use multiple version of the .NET framework.

The code enumerates all the Application Pools and then find all of the applications in that pool. It then checks for the version of the .NET framework which handles the .ASPX file extension.

It saves the unique versions of the .NET Framework found and if it finds multiple versions installed will list all of the applications using that Application Poll and display the path and the version being used. This will allow you to find a potential problem which could be hard to track down normally.

Calling Usage

cscript CheckForMultipleVersionsOfDotNetFramework.vbs

Example Output

AppPool #1
No applications using this pool!

DefaultAppPool

Warning multiple version of the .NET framework detected!

Found references to v1.1.4322
Found references to v2.0.50727

//localhost/W3SVC/1/ROO                                           - v1.1.4322
//localhost/W3SVC/1198258389/ROO                         - v1.1.4322
//localhost/W3SVC/1280263431/ROO                         - v1.1.4322
//localhost/W3SVC/1388032739/ROO                         - v1.1.4322
//localhost/W3SVC/1849151055/ROO                         - v1.1.4322
//localhost/W3SVC/1957176745/ROO                         - v1.1.4322
//localhost/W3SVC/4/ROO                                           - v1.1.4322
//localhost/W3SVC/415889539/ROO                           - v1.1.4322
//localhost/W3SVC/1/ROOT/Monito                            - v2.0.50727
//localhost/W3SVC/1/ROOT/Monitorin                        - v1.1.4322
//localhost/W3SVC/1/ROOT/NetTracke                       - v1.1.4322

ExchangeApplicationPool
Found references to v1.1.4322

ExchangeMobileBrowseApplicationPool
Found references to v1.1.4322

MSSharePointAppPool
Found references to v1.1.4322

MyAppPool1
No applications using this pool!

Source Code

You can download the source code here.

option explicit
dim AppsInPool, objAppPool, index, IISObj, IISPath, Version, pos
Dim Versions(), objAppPools
function FindASPXScriptMapVersion(ScriptMaps)
 Dim pos, ScriptMap
 for pos = lbound(ScriptMaps) to UBOund(ScriptMaps)
   ScriptMap = lcase(ScriptMaps(POS))
   if (left(ScriptMap, 5) = ".aspx") then
    FindASPXScriptMapVersion = mid(ScriptMap, 42)
    FindASPXScriptMapVersion = left(FindASPXScriptMapVersion, _
     instr(FindASPXScriptMapVersion, "\")-1)
    exit function
   end if
 next 
 FindASPXScriptMapVersion = ""
end function
function AddVersion(Version, Path)
 dim Found, pos
 Found = false
 for pos = lbound(Versions) to UBound(Versions)-1
  if (Versions(pos) = Version) then
   Found = true
  end if
 next
 if (Found = false) then
  redim preserve Versions(ubound(Versions)+1)
  Versions(ubound(Versions)-1)= Version
 end if
end function
Set objAppPools = GetObject("IIS://localhost/W3SVC/AppPools")
for each objAppPool in objAppPools
 Redim Versions(0)
 Set objAppPool = GetObject("IIS://localhost/W3SVC/AppPools/" & objAppPool.Name )
 WScript.echo objAppPool.Name 
 AppsInPool= objAppPool.EnumAppsInPool()
 if (ubound(AppsInPool) = -1) then
  WScript.echo vbtab  & "No applications using this pool!"
 else
  for index = lbound(AppsInPool) to UBound(AppsInPool)
   IISPath = AppsInPool(index)
   IISPath = "IIS://localhost/" & mid(IISPath,5, len(IISPath)-5)
   set IISObj = GetObject(IISPath)
   Version = FindASPXScriptMapVersion(IISObj.ScriptMaps)
   call AddVersion(Version, mid(IISPath,5, len(IISPath)-5))
  next
  if (ubound(Versions)> 1) then
   WScript.Echo vbcrlf & vbtab & _
    "Warning multiple version of the .NET framework detected!" & vbcrlf
   
   for pos = lbound(Versions) to ubound(Versions)-1
    WScript.echo vbtab & "Found references to " &  Versions(pos) 
   next
   WScript.echo ""
   for index = lbound(AppsInPool) to UBound(AppsInPool)
    IISPath = AppsInPool(index)
    IISPath = "IIS://localhost/" & mid(IISPath,5, len(IISPath)-5)
    set IISObj = GetObject(IISPath)
    Version = FindASPXScriptMapVersion(IISObj.ScriptMaps)
    WScript.echo vbtab & mid(IISPath,5, len(IISPath)-5) & _
     space(70 - len(IISpath)) & " - " & Version
   next
  else
   for pos = lbound(Versions) to ubound(Versions)-1
    WScript.echo vbtab & "Found references to " &  Versions(pos) 
   next  
  end if
 end if
 WScript.echo ""
next

IIS 6 - Creating an application and setting the application pool using ADSI

Chris Crowe — Sun, 30 Jul 2006 07:06:00 GMT

I received a request from visitor to my blog on how to set an application pool to a new folder he created.

"
I have a small web server running IIS 6 and I host small sites for friends and family all under one domain. To keep them separate I put each of their sites into a subfolder and drop it into different pools.

To date I've been doing this manually. I've been trying to get my mind wrapped around this ADSI stuff to automate this process a bit but I'm coming up short.

Here's what I do now.. if you have a few moments can you tell me how I might go about automating this process?

I make a subfolder (call it Test) in the root of my website.
I go into IIS Manager, expand the website, then right click on Test / Properties.
I click Create to make it into an application.
I change the application pool from Default to "familypool" then Apply.
"

The following code will allow you to create an application and assign the application pool "familypool" to the new directory. Note the application pool “familypool“ must already have been created.

option explicit

dim IIsWebVDirObj
dim IIsWebVDirRootObj
dim NewFolderName

NewFolderName = "Test"

const CreateNewApplicationPool = true
const UseExistingApplicationPool = false


' Create the Metabase entry
Set IIsWebVDirRootObj = GetObject("IIS://LocalHost/W3SVC/1/Root")
Set IIsWebVDirObj = IIsWebVDirRootObj.Create("IIsWebDirectory", NewFolderName)

IIsWebVDirObj.AppCreate3 2, " familypool", UseExistingApplicationPool
IIsWebVDirObj.AppFriendlyName = "My App Friendly Name"
IIsWebVDirObj.SetInfo

In the code above we have made some assumptions:

The web site we are assigning it to is the default web site. This has an instance ID of 1.
The IISWebDirectory does not exist in the Metabase. If it does it will cause an error as would be the case if you run the code twice.

In the case of the 2nd assumption above we would need to change the code from

Set IIsWebVDirRootObj = GetObject("IIS://LocalHost/W3SVC/1/Root")
Set IIsWebVDirObj = IIsWebVDirRootObj.Create("IIsWebDirectory", NewFolderName)

' Load the Metabase entry if it does exist
Set IIsWebVDirObj = GetObject("IIS://localhost/W3SVC/1/Root/" & NewFolderName)

IIS 6 Application Pools and ADSI

Chris Crowe — Wed, 12 Jul 2006 04:43:00 GMT

An application pool provides you with a way of isolating Web sites and Directories from each other even though they are being hosted on a common server. Each application pool is given its own set of server resources and can be configured with different identities. That way, if a Web site crashes, it won’t effect sites in other application pools.

A example of this is a Web site which has a memory leak. If all of the Web sites hosted on a particular server were to share the system resources as was the case with IIS 5.1 and earlier and one of the Web sites had a memory leak, it could potentially take memory away from the other hosted sites.

If the leaky site were in its own application pool though, the memory leak would not effect any other site because each application pool has its own server resources including memory.

On earlier versions of IIS you could only configure your sites to run either Low ( In Process ) with the IIS Engine, Medium ( Pooled ) where all applications shared a pool of memory, and High (Out Of Process). The problem with this is that a bad application could depending on the isolation level take down the IIS server, or all other sites in the Medium ( Pooled ) model.

Each application pool can be recycled based on a memory limit, the time of day, a number of requests or just after a period of time. Each application pool can also run with its own identity which can be either Local System, Local Service, Network Service or a custom credential.

Application pools are available only when IIS is running in worker process isolation mode (this is the default). If you are running IIS in IIS 5 isolation mode, then the application pools will not be accessible to you.

There is only one application pool by default called DefaultAppPool. When you create new Web sites, the newly created sites by default will use the DefaultAppPool unless you reconfigure the site after it is created. IIS does not automatically create a separate application pool for each Web site.

Note: If you are running ASP.NET 1.1 and 2.0 then they must run in two different application pools as you can only load one version of the .NET framework into an application pool.

Below are a number of very simple scripts that you could use to view / add and edit application pools.

Note: Application Pools are only supported on IIS 6 and later.

Enumerating Application Pools

This simple script will simply display the name of each application pool on the local server.

option explicit

dim objAppPools, objAppPool

Set objAppPools = GetObject("IIS://localhost/W3SVC/AppPools")
for each objAppPool in objAppPools
	WScript.echo objAppPool.Name 
next

Enumerating Applications in an Application Pool

This script will display the web sites / directories that are using the DefaultAppPool

option explicit

dim Applications, objAppPool, index

Set objAppPool = GetObject("IIS://localhost/W3SVC/AppPools/DefaultAppPool")
WScript.echo objAppPool.Name 

Applications = objAppPool.EnumAppsInPool()
for index = 0 to UBound(Applications)
	WScript.echo "   " & Applications(index)
next

Enumerating Application Pool Properties

This script will display all properties of an application pool by looking at the Schema object for an Application Pool.

option explicit

dim Applications, objAppPools, objAppPool, index, IIsSchemaObject
dim PropertyName, IIsAppPoolObject, ValueList

set IIsSchemaObject = GetObject("IIS://localhost/schema/IIsApplicationPool")
set IIsAppPoolObject = GetObject("IIS://localhost/W3SVC/AppPools/DefaultAppPool")

on error resume next

For Each PropertyName In IIsSchemaObject.MandatoryProperties
	WScript.echo PropertyName
next

For Each PropertyName In IIsSchemaObject.OptionalProperties
	WScript.echo PropertyName
	ValueList = IIsAppPoolObject.Get(PropertyName)
	if (isArray(ValueList) = true) then
		for index = lbound(ValueList) to ubound(ValueList)
			WScript.echo " " & index & " - " & ValueList(index)
		next
	else
		WScript.echo " " & ValueList
	end if
next

Enumerating the Periodic Recycling of all Application Pools

This script will display the recycling settings of all application pools. You may find that your application stops briefly and that could be caused by the application pool being recycled every 1740 minutes ( every 29 hours) which is the default.

option explicit

dim objAppPools, objAppPool, Schedule

Set objAppPools = GetObject("IIS://localhost/W3SVC/AppPools")
for each objAppPool in objAppPools
	WScript.echo objAppPool.Name
	WScript.echo "  Restart Time           : " & objAppPool.PeriodicRestartTime & " seconds"
	WScript.echo "  Restart Requests       : " & objAppPool.PeriodicRestartRequests
	WScript.echo "  Restart Memory         : " & objAppPool.PeriodicRestartMemory
	WScript.echo "  Restart Private Memory : " & objAppPool.PeriodicRestartPrivateMemory
	WScript.echo "  Restart Requests       : " & objAppPool.PeriodicRestartRequests
	for each Schedule in objAppPool.PeriodicRestartSchedule
		WScript.echo "  Restart At             : " & Schedule
	next
	WScript.echo
next

Creating an Application Pool

This script will create a new application pool using the defaults.

strAppPool = "MyAppPool1"
Set objAppPools = GetObject("IIS://localhost/W3SVC/AppPools")
Set objAppPool = objAppPools.Create("IIsApplicationPool", strAppPool)
objAppPool.SetInfo

Creating an Application Pool to run with a specific identity

This script will create a new application pool to run as a custom identity. This custom identity could be a local or domain account. You will need to add the user account into the IIS_WPG group on the IIS server. This is because this group has been assigned permissions that the application pool will need to run properly.

strAppPool = "MyAppPool2"
Set objAppPools = GetObject("IIS://localhost/W3SVC/AppPools")
Set objAppPool = objAppPools.Create("IIsApplicationPool", strAppPool)

' 0 = Local System
' 1 = Local Service
' 2 = Network Service
' 3 = Custom Identity -> also set WAMUserName and WAMUserPass
objAppPool.AppPoolIdentityType = 3

' Note: WamUserName must be added to the IIS_WPG group to have correct security rights
objAppPool.WAMUserName = "DOMAIN\Username"
objAppPool.WAMUserPass = "Password"

objAppPool.SetInfo

Starting an Application Pool

This script will allow you to start an application pool. You can also specify Stop() and Recycle() instead of Start().

option explicit

dim objAppPool

Set objAppPool = GetObject("IIS://localhost/W3SVC/AppPools/DefaultAppPool")
objAppPool.Start()

Hopefully these simple scripts will show you how easy Application Pools are to create and enumerate.

VBScript - Modified version of Mk3Site.vbs

Chris Crowe — Tue, 11 Jul 2006 06:37:00 GMT

This script is a modified version of the IIS 5 Mk3Site.vbs script.

I had a request to do some work and the customer would pay me to re-write the script to support some additional features.

I decided to do the work for free and donate the script to the community. It may have some use for some people.

The new features are:

Ability to set the application protection to Low, Medium or High
Ability to set the Execute options to None, Scripts or Executables
Ability to change the log file period
Ability to change the log directory

This script was updated from a previously updated script I wrote back in 2001 and is available from www.iisfaq.com

The new features of that script were:

Ability to setup URL redirection while creating the site.

You can download the script from here.

'------------------------------------------------------------------------------------------------
'
' This is a simple script to create a new virtual web server.
'
' Usage: MakeWebSite      <--RootDirectory|-r ROOT DIRECTORY>
'                         <--Comment|-t SERVER COMMENT>
'                         [--computer|-c COMPUTER1[,COMPUTER2...]]
'                         [--HostName|-h HOST NAME[,HOSTNAME2...]]
'                         [--port|-o PORT NUM]
'                         [--IPAddress|-i IP ADDRESS]
'                         [--SiteNumber|-n SITENUMBER]
'                         [--DontStart]
'                         [--verbose|-v]
'                         [--Write]"
'                         [--Execute { NONE, SCRIPTS, EXECUTABLES } ]"
'                         [--AppProtection { LOW, MEDIUM, HIGH } ]"
'                         [--AppName Name]"
'                         [--LogPeriod { DAILY, WEEKLY, MONTHLY, HOURLY} ]"
'                         [--LogFolder LogFileDirectory]"
'                         [--URL Redirectionpath]
'                         [--URLExact]
'                         [--URLChildOnly]
'                         [--URLPermanent]
'                         [--help|-?]
'
' IP ADDRESS            The IP Address to assign to the new server.  Optional.
' HOST NAME             The host name of the web site for host headers.
'      WARNING: Only use Host Name if DNS is set up find the server.
' PORT NUM              The port to which the server should bind
' ROOT DIRECTORY        Full path to the root directory for the new server.
' SERVER COMMENT        The server comment -- this is the name that appers in the MMC.
' SITENUMBER      The Site Number is the number in the path that the web server
'      will be created at.  i.e. w3svc/3
'
' Example 1: MakeWebSite.vbs -r D:\Roots\Company11 --DontStart -t "My Company Site"
' Example 2: MakeWebSite.vbs -r C:\Inetpub\wwwroot -t Test -o 8080
'
'
' Modified by chris crowe - www.iisfaq.com to support multiple host headers and URL Redirection
'------------------------------------------------------------------------------------------------

' Force explicit declaration of all variables
Option Explicit
'On Error Resume Next
Dim ArgIPAddress, ArgRootDirectory, ArgServerComment, ArgSkeletalDir, ArgHostName, ArgPort
Dim ArgComputers, ArgStart
Dim ArgSiteNumber
Dim oArgs, ArgNum
Dim verbose, FSO
' Chris Crowe - blog.crowe.co.nz
dim ArgLogFolder
dim ArgLogFilePeriod
dim ArgAppFriendlyName
dim ArgAppProtection
dim ArgExecute
dim ArgExecuteScripts
dim ArgExecuteExecutables 
dim ArgWrite
const MD_LOGFILE_PERIOD_MAXSIZE = 0 ' Create new log file after reaching maximum size. 
const MD_LOGFILE_PERIOD_DAILY   = 1 ' Create new log file daily. 
const MD_LOGFILE_PERIOD_WEEKLY  = 2 ' Create new log file weekly. 
const MD_LOGFILE_PERIOD_MONTHLY = 3 ' Create new log file monthly. 
const MD_LOGFILE_PERIOD_HOURLY  = 4 ' Create a new log file hourly. 
' Chris Crowe - iisfaq.com
Dim ArgURL, ArgURLExact, ArgURLChildOnly, ArgURLPermanent
ArgIPAddress = ""
ArgHostName = ""
ArgPort = 80
ArgStart = True
ArgComputers = Array(1)
ArgComputers(0) = "LocalHost"
ArgSiteNumber = 0
verbose = false
' Chris Crowe - blog.crowe.co.nz
ArgLogFolder            = ""
ArgLogFilePeriod        = ""
ArgAppFriendlyName      = ""
ArgAppProtection        = 2
ArgExecute              = ""
ArgWrite                = false
' Chris Crowe - iisfaq.com
ArgURL = ""
ArgURLChildonly = false
ArgURLExact = false
ArgURLPermanent = false
Set oArgs = WScript.Arguments
ArgNum = 0
While ArgNum < oArgs.Count
 Select Case LCase(oArgs(ArgNum))
  Case "--port","-o":
   ArgNum = ArgNum + 1
   ArgPort = oArgs(ArgNum) 
  Case "--ipaddress","-i":
   ArgNum = ArgNum + 1
   ArgIPAddress = oArgs(ArgNum)
  Case "--rootdirectory","-r": 
   ArgNum = ArgNum + 1
   ArgRootDirectory = oArgs(ArgNum)
  Case "--comment","-t":
   ArgNum = ArgNum + 1
   ArgServerComment = oArgs(ArgNum)
  Case "--hostname","-h":
   ArgNum = ArgNum + 1
   ArgHostName = oArgs(ArgNum)
  Case "--computer","-c":
   ArgNum = ArgNum + 1
   ArgComputers = Split(oArgs(ArgNum), ",", -1)
  Case "--sitenumber","-n":
   ArgNum = ArgNum + 1
   ArgSiteNumber = CLng(oArgs(ArgNum))
        ' Chris Crowe - blog.crowe.co.nz
  Case "--logfolder": 
   ArgNum = ArgNum + 1
   ArgLogFolder = oArgs(ArgNum)
  Case "--logperiod": 
   ArgNum = ArgNum + 1
   ArgLogFilePeriod = oArgs(ArgNum)
  Case "--appname": 
   ArgNum = ArgNum + 1
   ArgAppFriendlyName = oArgs(ArgNum)
  Case "--appprotection": 
   ArgNum = ArgNum + 1
   ArgAppProtection= oArgs(ArgNum)
  Case "--execute": 
   ArgNum = ArgNum + 1
   ArgExecute = oArgs(ArgNum)
  Case "--write"
   ArgWrite = true
  
  ' Chris Crowe - iisfaq.com
  Case "--url","-u": 
   ArgNum = ArgNum + 1
   ArgURL = oArgs(ArgNum)
  Case "--urlexact"
   ArgURLEXACT = true
  Case "--urlchildonly"
   ArgURLChildOnly = true
  Case "--urlpermanent"
   ArgURLPERMANENT = true
   
  Case "--dontstart":
   ArgStart = False
  Case "--help","-?":
   Call DisplayUsage
  Case "--verbose", "-v":
   verbose = true
  Case Else:
   WScript.Echo "Unknown argument "& oArgs(ArgNum)
   Call DisplayUsage
 End Select 
 ArgNum = ArgNum + 1
Wend
' Chris Crowe - iisfaq.com
If (ArgRootDirectory = "") Then
 WScript.Echo "Missing Root Directory (Required even with URL redirection path)"
 WScript.Echo ""
 Call DisplayUsage
 WScript.Quit(1)
End If
' Check if the root directory exists
Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
  if (FSO.FolderExists(ArgRootDirectory) = False) then
    WScript.echo "The specified root directory does not exist : '" & ArgRootDirectory & "'"
    WScript.Quit(2)
  end if
  
  
  ' Chris Crowe - July 2006
  if (ArgLogFolder > "") then
      if (FSO.FolderExists(ArgLogFolder) = False) then
        WScript.echo "The specified LogFolder directory does not exist : " & ArgLogFolder
        WScript.Quit(2)
      end if
  end if  
  
Set FSO = Nothing

' Chris Crowe - July 2006
if (ArgExecute> "") then
    ArgExecute = ucase(ArgExecute)
    if (ArgExecute = "NONE") then 
        ArgExecuteScripts = false
        ArgExecuteExecutables = false
    elseif (ArgExecute = "SCRIPTS") then 
        ArgExecuteScripts = true
        ArgExecuteExecutables = false
    elseif (ArgExecute = "EXECUTABLES") then 
        ArgExecuteScripts = true
        ArgExecuteExecutables = true
    else
      WScript.echo "The specified Execute value is invalid : " & ArgAppProtection
      WScript.Quit(2)
    end if
end if
if (ArgAppProtection > "") then
    ArgAppProtection = ucase(ArgAppProtection)
    if (ArgAppProtection = "LOW") then ArgAppProtection = 0
    if (ArgAppProtection = "INPROCESS") then ArgAppProtection = 0
    
    if (ArgAppProtection = "HIGH") then ArgAppProtection = 1
    if (ArgAppProtection = "OUTOFPROCESS") then ArgAppProtection = 1
    
    if (ArgAppProtection = "MEDIUM") then ArgAppProtection= 2
    if (ArgAppProtection = "POOLED") then ArgAppProtection = 2
    
    if ((ArgAppProtection = 0) or (ArgAppProtection = 1) or (ArgAppProtection = 2)) then
    else
      WScript.echo "The specified AppProtection value is invalid : " & ArgAppProtection
      WScript.Quit(2)
    end if
end if  
if (ArgLogFilePeriod > "") then
    ArgLogFilePeriod = ucase(ArgLogFilePeriod)
    if (ArgLogFilePeriod = "DAILY") then ArgLogFilePeriod = 1
    if (ArgLogFilePeriod = "WEEKLY") then ArgLogFilePeriod = 2   
    if (ArgLogFilePeriod = "MONTHLY") then ArgLogFilePeriod = 3
    if (ArgLogFilePeriod = "HOURLY") then ArgLogFilePeriod = 4
    
    if ((ArgLogFilePeriod= 0) or (ArgLogFilePeriod= 1) or (ArgLogFilePeriod= 2) or (ArgLogFilePeriod= 3)) then
    else
      WScript.echo "The specified LogFilePeriod is invalid : " & ArgLogFilePeriod
      WScript.Quit(2)
    end if
end if  

If (ArgServerComment = "") Then
 WScript.Echo "Missing Server Comment"
 WScript.Echo ""
 Call DisplayUsage
 WScript.Quit(1)
End If
' end - chris Crowe - iisfaq.com
' chris Crowe - iisfaq.com
Call ASTCreateWebSite(ArgIPAddress, ArgRootDirectory, ArgURL, ArgURLEXACT, ArgURLCHILDONLY, ArgURLPERMANENT, 
                      ArgServerComment, ArgHostName, ArgPort, ArgComputers, ArgStart)
' chris Crowe - iisfaq.com
Sub ASTCreateWebSite(IPAddress, RootDirectory, URL, ArgURLEXACT, ArgURLCHILDONLY, ArgURLPERMANENT, 
                     ServerComment, HostName, PortNum, Computers, Start)
 Dim w3svc, WebServer, NewWebServer, NewDir, Bindings, BindingString, NewBindings, ComputerIndex
 Dim Index, SiteObj, bDone
 Dim comp, BindingIndex, HostNameINdex, HostNames
 
   'Chris Crowe - www.iisfaq.com
 Dim URLOPTIONS 
 
 On Error Resume Next
 hostNames = Split(HostName,",")
 For ComputerIndex = 0 To UBound(Computers)
  comp = Computers(ComputerIndex)
  If ComputerIndex <> UBound(Computers) Then
   Trace "Creating web site on " & comp & "."
  End If
  ' Grab the web service object
  Err.Clear
  Set w3svc = GetObject("IIS://" & comp & "/w3svc")
  If Err.Number <> 0 Then
   Display "Unable to open: "&"IIS://" & comp & "/w3svc"
  End If
  Trace "Making sure this web server doesn't conflict with another..."
  For Each WebServer in w3svc
   If WebServer.Class = "IIsWebServer" Then
    Bindings = WebServer.ServerBindings
    For HostNameINdex = 0 To UBound(HostNames)
     for BindingIndex = 0 to Ubound(Bindings)
      BindingString = IpAddress & ":" & PortNum & ":" & HostNames(HostNameINdex)
      If (BindingString = bindings(BindingIndex)) Then
       Trace "The server bindings you specified are duplicated in another virtual web server."
       Trace "The Web Server name is [" & WebServer.ServerComment & "], Instance ID [" & WebServer.name & "]"
       Trace "The Conflicting Bindings are at index [" & bindingIndex & "], [" & bindings(BindingIndex) & "]"
       WScript.Quit (1)
      End If
     next
    next
   End If
  Next
  Index = 1
  bDone = False
  Trace "Creating new web server..."
  ' If the user specified a SiteNumber, then use that.  Otherwise,
  ' test successive numbers under w3svc until an unoccupied slot is found
  If ArgSiteNumber <> 0 Then
   Set NewWebServer = w3svc.Create("IIsWebServer", ArgSiteNumber)
   NewWebServer.SetInfo
   If (Err.Number <> 0) Then
    WScript.Echo "Couldn't create a web site with the specified number: " & ArgSiteNumber
    WScript.Quit (1)
   Else
    Err.Clear
    ' Verify that the newly created site can be retrieved
    Set SiteObj = GetObject("IIS://"&comp&"/w3svc/" & ArgSiteNumber)
    If (Err.Number = 0) Then
     bDone = True
     Trace "Web server created. Path is - "&"IIS://"&comp&"/w3svc/" & ArgSiteNumber
    Else
     WScript.Echo "Couldn't create a web site with the specified number: " & ArgSiteNumber
     WScript.Quit (1)
    End If
   End If
  Else
   While (Not bDone)
    Err.Clear
    Set SiteObj = GetObject("IIS://"&comp&"/w3svc/" & Index)
    If (Err.Number = 0) Then
     ' A web server is already defined at this position so increment
     Index = Index + 1
    Else
     Err.Clear
     Set NewWebServer = w3svc.Create("IIsWebServer", Index)
     NewWebServer.SetInfo
     If (Err.Number <> 0) Then
      ' If call to Create failed then try the next number
      Index = Index + 1
     Else
      Err.Clear
      ' Verify that the newly created site can be retrieved
      Set SiteObj = GetObject("IIS://"&comp&"/w3svc/" & Index)
      If (Err.Number = 0) Then
       bDone = True
       Trace "Web server created. Path is - "&"IIS://"&comp&"/w3svc/" & Index
      Else
       Index = Index + 1
      End If
     End If
    End If
    ' sanity check
    If (Index > 10000) Then
     Trace "Seem to be unable to create new web server.  Server number is "&Index&"."
     WScript.Quit (1)
    End If
   Wend
  End If
on error goto 0
  redim NewBindings (ubound(HostNames))
  For HostNameINdex = 0 To UBound(HostNames)
   BindingString = IpAddress & ":" & PortNum & ":" & HostNames(HostNameINdex)
   Trace "Binding = " & BindingString 
   NewBindings(HostNameINdex) = BindingString
  next
        ' Modified by Chris Crowe - July 2006 (Start)
  
  if (ArgLogFolder > "") then
      NewWebServer.LogFileDirectory = ArgLogFolder
  end if
  
  if (ArgLogFilePeriod > "") then
         NewWebServer.LogFilePeriod = ArgLogFilePeriod
  end if
  
  ' Modified by Chris Crowe - July 2006 (End)
  NewWebServer.ServerBindings = NewBindings
  NewWebServer.ServerComment = ServerComment
  NewWebServer.SetInfo
  ' Now create the root directory object.
  Trace "Setting the home directory..."
  Set NewDir = NewWebServer.Create("IIsWebVirtualDir", "ROOT")
  NewDir.Path = RootDirectory
  NewDir.AccessRead = true
  ' Chris Crowe - July 2006
  if (ArgWrite = true) then
      NewDir.AccessWrite = true
  end if
  if (ArgExecute > "") then
      NewDir.AccessScript = ArgExecuteScripts
      NewDir.AccessExecute = ArgExecuteExecutables
  end if
  
  ' Modified by Chris crowe - January 2002
  if (URL <> "") then
     trace "Redirection to a URL: " & URL
     URLOPTIONS= ""
     if (ArgURLEXACT = true) then
     URLOPTIONS = ", EXACT_DESTINATION"
     end if
     if (ArgURLCHILDONLY = true) then
   if (URLOPTIONS > "") then
    URLOPTIONS = URLOPTIONS & ", CHILD_ONLY" 
   else
      URLOPTIONS = ", CHILD_ONLY" 
   end if
     end if
     if (ArgURLPERMANENT = true) then
   if (URLOPTIONS > "") then
    URLOPTIONS = URLOPTIONS & ", PERMANENT" 
   else
      URLOPTIONS = ", PERMANENT" 
   end if
     end if
     trace "Redirection Flags : " & URLOPTIONS
        newDir.httpredirect= URL & URLOPTIONS
  end if
  ' Modified by Chris crowe - January 2002
      
  
  Err.Clear
  NewDir.SetInfo
  ' Chris Crowe - July 2006
  NewDir.AppCreate2 (ArgAppProtection)
  
  if (ArgAppFriendlyName > "") then
      NewDir.AppFriendlyName = ArgAppFriendlyName
      NewDir.SetInfo
  end if
  If (Err.Number = 0) Then
   Trace "Home directory set."
  Else
   Display "Error setting home directory."
  End If
  Trace "Web site created!"
  If Start = True Then
   Trace "Attempting to start new web server..."
   Err.Clear
   Set NewWebServer = GetObject("IIS://" & comp & "/w3svc/" & Index)
   NewWebServer.Start
   If Err.Number <> 0 Then
    Display "Error starting web server!"
    Err.Clear
   Else
    Trace "Web server started succesfully!"
   End If
  End If
 Next
End Sub

' Display the usage message
Sub DisplayUsage
 WScript.Echo "Usage: MakeWebSite <--RootDirectory|-r ROOT DIRECTORY>"
 WScript.Echo "                   <--Comment|-t SERVER COMMENT>"
 WScript.Echo "                   [--computer|-c COMPUTER1[,COMPUTER2...]]"
 WScript.Echo "                   [--port|-o PORT NUM]"
 WScript.Echo "                   [--IPAddress|-i IP ADDRESS]"
 WScript.Echo "                   [--HostName|-h HOST NAME[,HOSTNAME2...]]"
 WScript.Echo "                   [--SiteNumber|-n SITENUMBER]"
 WScript.Echo "                   [--AppProtection Level { LOW, MEDIUM, HIGH } ]"
 WScript.Echo "                   [--AppName Name]"
 WScript.Echo "                   [--Write]"
 WScript.Echo "                   [--Execute { NONE, SCRIPTS, EXECUTABLES } ]"
 WScript.Echo "                   [--LogPeriod LogFilePeriod { DAILY, WEEKLY, MONTHLY, HOURLY}]"
 WScript.Echo "                   [--LogFolder LogFileDirectory]"
 WScript.Echo "                   [--URL RedirectionPath]"
 WScript.Echo "                   [--URLExact]"
 WScript.Echo "                   [--URLChildOnly]"
 WScript.Echo "                   [--URLPermanent]"
 WScript.Echo "                   [--DontStart]"
 WScript.Echo "                   [--verbose|-v]"
 WScript.Echo "                   [--help|-?]"
 WScript.Echo ""
 WScript.Echo "WARNING: Only use Host Name if DNS is set up find the server."
 WScript.Echo ""
 WScript.Echo "Example 1: MakeWebSite.vbs -r D:\Roots\Company11 --DontStart -t ""My Company Site"""
 WScript.Echo "Example 2: MakeWebSite.vbs -r D:\Roots\Company11 -h ""www.iisfaq.com,www.iis.com"" --DontStart 
                          -t ""My Company Site"""
 WScript.Echo "Example 3: MakeWebSite.vbs -r D:\Roots\Company11 -i 192.168.0.1 -t ""My Company Site"" 
                          --URL http://www.iisfaq.com --URLExact --URLPermanent"
 WScript.Echo "Example 4: MakeWebSite.vbs -r D:\Roots\Company11 --DontStart -t ""My Company Site"" 
                          --LogPeriod MONTHLY --LogFolder c:\Root\Company1"
 WScript.Echo "Example 5: MakeWebSite.vbs -r D:\Roots\Company11 --DontStart -t ""My Company Site"" 
                          --AppName XYZ --LogFolder c:\Root\Company1"
 WScript.Echo ""
 WScript.Echo "Note: URLRedirection requires a HTTP:// prefix and a root directory also!"
 WScript.Echo "      Write enables write access to the directory"
 WScript.Echo ""
 WScript.Quit (1)
End Sub
Sub Display(Msg)
 WScript.Echo Now & ". Error Code: " & Hex(Err) & " - " & err.Description &  " - " & Msg
End Sub
Sub Trace(Msg)
 if verbose = true then
  WScript.Echo Now & " : " & Msg 
 end if
End Sub

VBScript - How to search all sites and host headers for a particular string of characters?

Chris Crowe — Sat, 08 Jul 2006 22:15:00 GMT

The following script will allow you to search the local web server for all virtual servers that have been configured for a particular host header value.

The script requires you to specify a value to seach for as a command line parameter.

Example

cscript EnumByHostHeader.vbs SearchString

Where SearchString is some text to search for such as crowe

cscript EnumByHostHeader.vbs crowe

The expected result is something like the following

Searching for CROWE in the host headers

Web Site Instance ID - Server Comment - Host Header
126606719 - photos.crowe.co.nz - PHOTOS.CROWE.CO.NZ
1849151055 - rotties.crowe.co.nz - ROTTIES.CROWE.CO.NZ
2021379493 - Blog (Maintenance) - BLOG.CROWE.CO.NZ
415889539 - fish.crowe.co.nz - FISH.CROWE.CO.NZ

on error resume next
dim Contains
Set ArgObj = WScript.Arguments
If ArgObj.Count < 1 Then
Wscript.echo "Please specify the name or part name to look for in the host header field!"
Wscript.echo ""
Wscript.echo "Example"
Wscript.echo " cscript EnumByHostHeader.vbs ccrowe"
else
Contains = ucase(ArgObj.Item(0))
dim websrv, site
dim Found
dim webinfo
Found = false
WScript.echo "Searching for " & Contains & " in the host headers"
WScript.echo ""
    WScript.echo "Web Site Instance ID - Server Comment - Host Header"
set websrv = getobject("IIS://Localhost/W3SVC")
if (err <> 0) then
else
err.Clear
for each site in websrv
   if (site.classname = "IIsWebServer") then
    bindings = Site.ServerBindings
    For Index = LBound(bindings) To UBound(bindings)
     Values = split(bindings(Index), ":")
     HostHeader = ucase(Values(2))
     if (instr(HostHeader, Contains) > 0) then
      Found = true
      WScript.echo site.Name & " - " & _
                            site.ServerComment & " - " & _
                            HostHeader
     end if
    next
   end if
next
end if
if (Found = false) then
WScript.echo "The search term " & Contains & " was not found!"
end if
end if

Some examples of scripting of IIS using ADSI, WMI from VB and C# including the new Microsoft.Web.Administration namespace

Chris Crowe — Tue, 04 Jul 2006 09:18:00 GMT

Below are some simple examples of how to talk to IIS via ADSI, WMI and the new IIS 7 only .NET Managed Provider.

The IIS ADSI Provider

The IIS ADSI provider exposes COM Automation objects that you can use within command-line scripts, ASP pages, or custom applications to change IIS configuration values stored in the IIS metabase. IIS ADSI objects can be accessed and manipulated by any language that supports automation, such as Microsoft® Visual Basic® Scripting Edition (VBScript), Microsoft JScript®, Perl, Microsoft Active Server Pages (ASP), Visual Basic, Java, or Microsoft C++.

The IIS WMI Provider

Windows Management Instrumentation (WMI) is a technology that allows administrators to programmatically manage and configure the Windows operating system and Windows applications. Beginning with IIS 6.0, IIS includes a WMI provider that exposes programming interfaces that can be used to query and configure the IIS metabase.

The Microsoft.Web.Administration namespace in IIS 7

This is a new .NET managed namespace that will allow you to talk to IIS 7 and configure all aspects of the server. This API is designed to be simple to code against in an “intellisense-driven” sort of way. At the root level a class called ServerManager exposes all the functionality you will need. At this time it appears that this will not be able to be used from Windows XP but by the time Vista & Windows Server are released this may have been ported to run on a Windows XP client.

For more details on these technologies see the following resources:

Active Directory Service Interfaces Overview
http://www.microsoft.com/windows2000/techinfo/howitworks/activedirectory/adsilinks.asp
WMI - Windows Management Instrumentation
http://www.microsoft.com/whdc/system/pnppwr/wmi/default.mspx
Administering IIS Programmatically (IIS 6.0)
http://www.microsoft.com/technet/prodtechnol/WindowsServer2003/Library/IIS/9041b0a5-c314-46d9-8f56-01506687f357.mspx
Pre-release documentation on Microsoft.Web.Administration
http://windowssdk.msdn.microsoft.com/en-us/library/microsoft.web.administration.aspx

C# -Using System.DirectoryServices and ADSI

using System;
using System.Collections.Generic;
using System.Text;
// Must be specified and a reference added to System.DirectoryServices
using System.DirectoryServices;

namespace Console_EnumSites_ADSI_CSharp
{
    class Program
    {
        static void Main(string[] args)
        {
            DirectoryEntry entry = new DirectoryEntry("IIS://LocalHost/W3SVC");
            foreach (DirectoryEntry site in entry.Children)
            {
                if (site.SchemaClassName == "IIsWebServer")
                {
                    string ServerComment = site.Properties["ServerComment"].Value.ToString();
                    Console.WriteLine(ServerComment + " (" + site.Name + ")");
                }
            }
        }
    }
}

VB -Using ADSI

on error resume next

dim websrv, site
dim webinfo

set websrv = getobject("IIS://Localhost/W3SVC")
if (err <> 0) then
else
    err.Clear
    for each site in websrv
        if (site.classname = "IIsWebServer") then
            WScript.echo Site.ServerComment & " (" & Site.Name & ")"
        end if
    next
end if

C# -Using System.Managment and WMI

using System;
using System.Collections.Generic;
using System.Text;
using System.Management;

namespace Console_EnumSites_WMI_CSharp
{
    class Program
    {
        static void Main(string[] args)
        {
            ManagementScope oms = new ManagementScope(@"\\.\root\MicrosoftIISv2");
            oms.Connect();

            ObjectQuery oQuery = new ObjectQuery("select * from IISWebServerSetting");
            ManagementObjectSearcher oSearcher = new ManagementObjectSearcher(oms, oQuery);
            foreach (ManagementObject oreturn in oSearcher.Get())
            {
                Console.WriteLine(oreturn["ServerComment"]+" ("+oreturn["Name"]+")");
            }
            Console.Read();
        }
    }
}

C# -Using Microsoft.Web.Administration ( II7 Only )

using System;
using System.Collections.Generic;
using System.Text;
using Microsoft.Web.Administration;

namespace Console_EnumSites
{
    class Program
    {
        static void Main(string[] args)
        {
            ServerManager iisManager = new ServerManager();

            Console.WriteLine("Display IIS Sites in IIS 7");
            Console.WriteLine("".PadLeft(40,'-'));
            foreach(Site site in iisManager.Sites)
            {
                Console.WriteLine("{0} {1}", site.Id.ToString().PadRight(12), site.Name);                
            }
            Console.Read();
        }
    }
}

c# - How to display the HttpExpires property and display its meaning...

Chris Crowe — Fri, 30 Jun 2006 10:38:00 GMT

The HttpExpires property is documented at the following URL.

http://www.microsoft.com/technet/prodtechnol/WindowsServer2003/Library/IIS/3e1d9fbb-6910-4648-a2bb-11a945ca7980.mspx?mfr=true

This simple c# console application will display the settings for the HttpExpires property at the root level of the default web site.

Basically the value is encoded as follows:

If the value is a blank string then there is no content expiry.
If the value starts with a D, then it is using a dynamic expiration period. This period is appended after the D and is stored as the number of seconds in hexidecimal format.

Example: “D, 0x15180” - this 0x15180 is the same as 86,400 seconds or 1 day.
If the value starts with an S then the following value is a GMT time of when the expiration will take place.

Example: “S, Sat, 08 Jul 2006 12:00:00 GMT”

using System;
using System.Collections.Generic;
using System.Text;
using System.DirectoryServices;
namespace IISHTTPExpires
{
    class Program
    {
        static void Main(string[] args)
        {
            Console.WriteLine("IIS HTTP Expires - c#");
            Console.WriteLine();
            // Serve to connect to...
            string ServerName = "LocalHost";
            // Define the path to the metabase
            string MetabasePath = "IIS://" + ServerName + "/W3SVC/1/ROOT";
            try
            {
                // Talk to the IIS Metabase to read the MimeMap Metabase key
                DirectoryEntry Entry = new DirectoryEntry(MetabasePath);
                // Get the Mime Types as a collection
                PropertyValueCollection pvc = Entry.Properties["HTTPExpires"];
                string HttpExpires = pvc.Value.ToString();
                if (HttpExpires.Length == 0)
                {
                    Console.WriteLine("HttpExpires is not enabled!");
                }
                else
                {
                    char HttpExpiresType = HttpExpires[0];
                    switch (HttpExpiresType) { case 'D':
                            string Seconds = HttpExpires.Substring(3);
                            if (Seconds == "0")
                                Seconds = "Immediately";
                            else if (Seconds.StartsWith("0x")==true)
                                Seconds = "in " + int.Parse(HttpExpires.Substring(5),
                                    System.Globalization.NumberStyles.HexNumber).ToString() + " Seconds";
                            else
                                Seconds = "in " + Seconds + " Seconds";
                            Console.WriteLine("HttpExpires {0}", Seconds);
                            break;
                        case 'S':
                            Console.WriteLine("HttpExpires {0}", HttpExpires.Substring(2));
                            break;
                        default:
                            Console.WriteLine("Unknown HttpExpires Type : {0}", HttpExpiresType);
                            break;
                    }
                }
            }
            catch (Exception ex)
            {
                Console.WriteLine("Failed to read HttpExpires property with the following exception: \n{0}",
                    ex.Message);
            }
            finally
            {
                Console.Read();
            }
        }
    }
}